betti(ChainComplex) -- display of degrees in a chain complex

Synopsis

Usage:
betti C
Function: betti
Inputs:
- C, a chain complex
Outputs:
- a Betty tally, a diagram showing the degrees of the generators of the modules in C

Description

The diagram can be used to determine the degrees of the entries in the matrices of the differentials in the chain complex, provided they are homogeneous maps of degree 0.

Here is a sample diagram.

i1 : R = ZZ/101[a..h]

o1 = R

o1 : PolynomialRing

i2 : p = genericMatrix(R,a,2,4)

o2 = | a c e g |
     | b d f h |

             2       4
o2 : Matrix R  <--- R

i3 : q = generators gb p

o3 = | g e c a 0     0     0     0     0     0     |
     | h f d b fg-eh dg-ch bg-ah de-cf be-af bc-ad |

             2       10
o3 : Matrix R  <--- R

i4 : C = resolution cokernel leadTerm q

      2      10      14      7      1
o4 = R  <-- R   <-- R   <-- R  <-- R  <-- 0
                                           
     0      1       2       3      4      5

o4 : ChainComplex

i5 : betti C

            0  1  2 3 4
o5 = total: 2 10 14 7 1
         0: 2  4  6 4 1
         1: .  6  8 3 .

o5 : BettiTally

Column j of the top row of the diagram gives the rank of the free module C_j. (Columns are numbered from 0.) The entry in column j in the row labelled i is the number of basis elements of degree i+j in the free module C_j. When the chain complex is the resolution of a module the entries are the total and the graded Betti numbers of the module.

If the numbers are needed in a program, then they are accessible, because the value returned is a Betty tally, and the diagram you see on the screen is just the way it prints out.