実験的仕様の関数: 2.1 クオート

2.1 クオート

2.1.1 `quotetotex`, `quotetotex_env`

quotetotex(q): :: q を latex 形式で表現した文字列に変換する.
quotetotex_env(key,value): :: quotetotex の動作を制御するパラメータを変更する.
quotetotex_env(): :: quotetotex の動作を制御するパラメータの現在値を戻す.
quotetotex_env(0): :: quotetotex の動作を制御するパラメータをデフォールト値に戻す.

return: 文字列(quotetotex) またはリストまたはオブジェクト(quotetotex_env)
q: quote
key: 文字列
value: オブジェクト

quotetotex は q を latex 形式で表現した文字列に変換する.
以下 quotetotex_env のパラメータの意味を説明する.
conv_rule: 3 ビットを用いて変換ルールを指定する. 0ビット目は symbol_table による変換を行うか, 1ビット目は添字変換を行うか, 2ビット目は d から始まる変数名を微分作用素とみなして処理するか, を意味する. たとえば conv_rule として 3 を指定すると, 0ビット目, 1 ビット目が 1 となるので symbol_table による変換を行い, 添字変換をおこなう. 添字変換は数字と英字の境目および _ 記号を区切りとする. symbol_table による変換が最初に適用される. alpha, beta, 等は自動的をギリシャ文字に変換するテーブルは内蔵ずみ.
dp_vars_prefix: 分散表現多項式は x0, x1, ... の多項式として latex 形式に変換されるがこの x の部分を変更する.
dp_vars_origin: インデックスの始まりの値を指定する. デフォールトは 0.
dp_vars_hweyl: 分散表現多項式をワイル代数の元とみなして latex 形式に変換する. 偶数個変数があるときは最初の半分を x0, x1, ... に後半の半分を dx0, dx1, ... に変換する. 奇数個の場合は最後の変数が同時化変数として h で表示される.
dp_dvars_prefix: dp_vars_hweyl が 1 の時に後半部分の prefix を指定する. デフォールトは
dp_dvars_origin: dp_vars_hweyl が 1 の時のインデックスの始まりの値.
conv_func: ユーザ定義の変換関数をよぶ.

[3] quotetotex(quote(1/(x+1)));
\frac{ 1} { (  {x}+ 1)}
[4]  quotetotex(objtoquote(diff(x^x,x)));
   {x}^{  {x}- 1}   {x}+  \log( {x})   {x}^{ {x}}
[5] quotetotex_env("conv_rule",3);
[6] quotetotex(objtoquote( (alpha2beta+x_i_j)^2));
  {\alpha}_{2,\beta}^{ 2} +   2  {x}_{i,j}  {\alpha}_{2,\beta}+  {x}_{i,j}^{ 2}

参照: objtoquote print_tex_form(contrib)

ChangeLog

この関数は 2004年2月末から3月にかけて asir を knoppix 版 texmacs に対応させるために書かれた. Asir-contrib の print_tex_form がその原型であり, それを効率化しまた出力形式を改善した. OpenXM/src/kxx/ox_texmacs.c, OpenXM/src/texmacs も参照.
OpenXM/src/asir-contrib/packages/src/noro_print.rr 1.1–1.8, noro_print_default.rr 1.1–1.3 も参照.
変更を受けたファイルは OpenXM_contrib2/asir2000 の下の次のファイル. builtin/strobj.c 1.14–1.43, include/ca.h 1.46, io/cexpr.c 1.18, io/pexpr.c 1.32, io.sexpr.c 1.29, parse/arith.c 1.12, parse/parse.h 1.28–1.29, parse/quote.c 1.7–1.8, 1.12.
knoppix/math は福岡大学の濱田さんが中心となり開発されている.
dp_dvars_prefix, *_origin は builtin/strobj.c 1.46 で導入された.
Todo: quotetoterminalform (分散表現多項式の見易い出力).

2.1.2 `objtoquote`

objtoquote(ob): :: オブジェクトと quote 型のデータに変換する.

return: quote
ob: オブジェクト

objtoquote(ob) は, ob を quote 型のデータに変換する.

[1150] quotetolist(quote(1+2));
[b_op,+,[internal,1],[internal,2]]
[1151] quotetolist(objtoquote(1+x));
[b_op,+,[internal,x],[internal,1]]3

参照: @ref{quotetotex} @ref{quotetolist}

ChangeLog

この関数は quotetotex の前処理をするために書かれた.
asir-contrib の関数 quote_to_quote も参照.
OpenXM_contrib2/asir2000/builtin/print.c 1.16.

2.1.3 `flatten_quote`

flatten_quote(q,op): :: quote の括弧をとりさる.

return: Quote
q: Quote
op: 演算子を表す文字列.

Quote 型のデータは木構造をしている ( quotetolist 参照 ). quote_flatten() は, q の中にあられる演算子 op の子供ノードを平等にする. つまり演算子 op に関する括弧づけがあった場合それをすべてとりさる. たとえば (1+2)+(3+4) という表現を 1+2+3+4 に変換する.
現在の実装では n-ary の演算子は定義されていないので, 1+2+3 は実は 1+(2+3) と表現されている. つまり + 演算子は右結合的である.
R=0; for (I=0; I<N; I++) R = R+ P[I]; なる足し算を繰り返すと, + は左結合的になる. 右結合的に変換するには flatten_quote を呼ぶ.
名前は quote_flatten でなく flatten_quote である.

[1288] flatten_quote(quote((1+2)+(3+4*(x+3))),"+");
quote(1+2+3+4*(x+3))
[1289] flatten_quote(quote( (x*y)*(p*3)-(x*y)*z),"*");
quote(x*y*p*3-x*y*z)
[1290] quotetolist(quote(1+2+3));
[b_op,+,[b_op,+,[internal,1],[internal,2]],[internal,3]]

参照: @ref{quotetolist}, @ref{print_tex_form}(contrib)

ChangeLog

この関数は 2004-7-7 から 2004-7-8 にかけて quote に関する操作を研究するために実験的に書かれた. OpenXM/fb で蓄積された公式の不要な括弧をとりはずし, tex 形式に変換するのに応用.
変更をうけたソースコードは builtin/strobj.c 1.47, parse/eval.c 1.35, parse/parse.h 1.31, parse/quote.c 1.14–1.16.

2.1.4 `quote_to_funargs`, `funargs_to_quote`, `remove_paren`, `get_function_name`

quote_to_funargs(q): :: quote を funarg 形式(リスト) へ.
funargs_to_quote(f): :: funarg 形式を quote へ.
get_function_name(f): :: funarg 形式の op を文字列へ.
remove_paren(q): :: 上の関数を用いて書かれた余分な括弧を取り去る simplifier (asir-contrib マニュアルへ: todo)

return: quote(funargs_to_quote, remove_paren) かリスト(quote_to_funargs)
q: quote
f: リスト

quote_to_funargs は quote 型のデータ (内部的には FNODE) を quote への復元可能な形でリストへ変換する. quotetolist は quote をリストへ変換するが, 一部の情報を捨てるためもとの quote の復元はできない.
quote_to_funargs の戻り値は [fid, op, arg1, arg2, ...] なる形式をしている. ここで op は node の名前であり, 関数 get_function_name を用いて人間が読める形式で取りだせる. たとえば get_function_name(quote_to_funargs(quote(1+2))[1]) は "+" を戻す.
名前get_function_name はそのうち変更されるだろう.
下の例で quote_to_funargs(FA[2]); [34,[b_op,+,[internal,x],[internal,1]]] となる. 34 は I_PAREN を意味する. 数と意味の対応表は OpenXM/src/asir-contrib/packages/src/noro_simplify.rr または OpenXM_contrib2/asir2000/parse/parse.h を見よ. 以下の fid が 0, 1, 2, ... に対応づけられている. I_BOP, I_COP, I_AND, I_OR, I_NOT, I_CE, I_PRESELF, I_POSTSELF, I_FUNC, I_FUNC_OPT, I_IFUNC, I_MAP, I_RECMAP, I_PFDERIV, I_ANS, I_PVAR, I_ASSPVAR, I_FORMULA, I_LIST, I_STR, I_NEWCOMP, I_CAR, I_CDR, I_CAST, I_INDEX, I_EV, I_TIMER, I_GF2NGEN, I_GFPNGEN, I_GFSNGEN, I_LOP, I_OPT, I_GETOPT, I_POINT, I_PAREN, I_MINUS, I_NARYOP

次の例では (x+1)+(x+2) の括弧をはずして x+1+x+2 に変換している.

[0] ctrl("print_quote",1) $

[1] Q=quote((x+1)+(x+2));
[b_op,+,[u_op,(),[b_op,+,[internal,x],[internal,1]]],
        [u_op,(),[b_op,+,[internal,x],[internal,2]]]]

[2] FA=quote_to_funargs(Q);
[0,<...quoted...>,
  [u_op,(),[b_op,+,[internal,x],[internal,1]]],
  [u_op,(),[b_op,+,[internal,x],[internal,2]]]]

[3] FA2=quote_to_funargs(FA[2])[1];
[b_op,+,[internal,x],[internal,1]]

[4] FA3=quote_to_funargs(FA[3])[1];
[b_op,+,[internal,x],[internal,2]]

[5] funargs_to_quote([FA[0],FA[1],FA2,FA3]);
[b_op,+,[b_op,+,[internal,x],[internal,1]],
        [b_op,+,[internal,x],[internal,2]]]

次の例は OpenXM/asir-contrib 版の asir で実行.

[1287] load("noro_simplify.rr");
1
[1293] noro_simplify.remove_paren(quote( f(1-(x))));
quote(f(1-x))

funargs_to_quote を用いて既存の quote の子供を置き換えて新しい quote をつくり出せる.

[1184] R=quote_to_funargs(quote(a+(b+c)));
[0,<...quoted...>,<...quoted...>,<...quoted...>]
[1185] T=quote_to_funargs(quote(1+2));
[0,<...quoted...>,<...quoted...>,<...quoted...>]
[1186] funargs_to_quote([0,R[1],R[2],T[2]]);
quote(a+1)

参照: @ref{quotetolist}

ChangeLog

これらの関数は 2004-7-8 から開発のはじまっている quote の simplification 関連の実験的関数である. 変更をうけたソースコードは多岐にわたるのでまだ書かない.
括弧を取り去る問題は OpenXM/fb が蓄えている公式を tex で綺麗に表示するのが動機の一つ.
2004-6-26 の計算代数セミナーにおいて, 中川さんが simplifier についていろいろ問題提起をした (計算代数セミナービデオ参照).
parse/quote.c の strcut fid_spec fid_spec_tab[] の部分に書いてある形式に funargs_to_quote は変換する.

2.1.5 `eval_quote`

eval_quote(Q);: :: quote 型データ Q を asir のオブジェクトに変換する.

return: オブジェクト
Q: quote型

quote 型データ Q を asir のオブジェクトに変換する.
逆関数は objtoquote

ctrl("print_quote",2);
A=quote((x-1)^2+(x-1)+3);
     出力: ((((x)-(1))^(2))+((x)-(1)))+(3)
eval_quote(A);
     出力: x^2-x+3
print_input_form(A);     /* asir-contrib */
     出力: quote((x-1)^2+(x-1)+3)

参照: objtoquote, @ref{quotetolist}, @ref{eval_string}, @ref{quote_to_funargs}, @ref{funargs_to_quote}

ChangeLog

—–まだ書いてない.

2.1.6 `nqt_match`

nqt_match(Expr,Pattern[,Mode]): :: Expr が Pattern にマッチ(適合)すると 1 を戻す. しないと 0 を戻す.

return: 整数
Expr: quote型
Pattern: quote型
Mode: 整数

Expr が Pattern にマッチ(適合)すると 1 を戻す. しないと 0 を戻す.
適合した場合, 副作用として, Pattern に含まれるプログラム変数(大文字ではじまる変数)に適合した値が代入される.
nqt は normalized quote の略であり fnode標準形に変換してから適合検査をする. fnode標準形については qt_normalize を見よ.
Mode により展開方法を指定し, その展開方法により得られた Expr の fnode標準形と Pattern を比較する.

ctrl("print_quote",2);
A=quote((x-y)*(x+y));
nqt_match(A,quote(P*Q));
[P,Q]
    出力:  [x-y, x+y]
nqt_match(A,quote(P*Q),1);
    マッチしない.
nqt_match(A,quote(P*Q),2);
    マッチしない.
qt_normalize(A,1);
    出力:  ((x)^(2))+((x)*(y))+((-1)*((y)^(2)))+((-1)*(y)*(x))
qt_normalize(A,2);
    出力:  ((x)*(x))+((x)*(y))+((-1)*(y)*(x))+((-1)*(y)*(y))

参照: nqt_match_rewrite, qt_rewrite

ChangeLog

—– まだ書いてない.

2.1.7 `nqt_match_rewrite`

nqt_match_rewrite(Expr,Rule,Mode): :: Expr を Rule に従い書き換える.

return: quote型
Expr: quote型
Rule: [Pattern,Action] かまたは [Pattern,Condition,Action]. これらの要素はすべて quote型.
Mode: 整数

Expr を Rule に従い書き換える. Pattern に適合しない場合は Exprt 自体を戻す.
nqt は normalized quote の略であり fnode標準形に変換してから適合検査をする. fnode標準形については qt_normalize を見よ.

ctrl("print_quote",2);
nqt_match_rewrite(`x*y*z,[`X*Y,`X+Y],1);
   出力: (x)+((y)*(z))
A=`x*x;
nqt_match_rewrite(A,[`X*Y,`X+Y],1);
   出力: x^2   (マッチしていない)
nqt_match_rewrite(A,[`X*Y,`X+Y],2);
   出力: 2*x

適合についてのモードの違いを理解するために次の例および fnode標準形(qt_normalize) を参照.
quotetolist(qt_normalize(`x*x,0));
    出力:  [b_op,^,[internal,x],[internal,2]]
quotetolist(qt_normalize(`x*x,1));
    出力:  [b_op,^,[internal,x],[internal,2]]
quotetolist(qt_normalize(`x*x,2));
    出力:  [n_op,*,[internal,x],[internal,x]]

参照: nqt_match, qt_rewrite, qt_normalize

ChangeLog

—–まだ書いてない.

2.1.8 `qt_normalize`

qt_normalize(Expr[,Mode]): :: Expr を fnode標準形に変換する. Modeにより標準形への展開アルゴリズムを指定できる.

return: quote型
Expr: quote型
Mode: 整数

fnodeは quote型の実体である. fnode は木であり, 型 id および子供からなる. 型および子供を取り出す関数が funargs_to_quote である. また fnode をリストに変換する関数が quotetolist である.

fnode の標準形はパターンマッチング, 書き換えを容易におこなうために導入された. fnode の標準形を fn と書くとき, 標準形の BNF風表現での定義は以下のとおり.

 fn           = formula | functor(nf [,...]) | sum_of_monom
     fnode の標準形.  functor は関数よびだしみたいなもの.
 sum_of_monom = monom [+ ...]
     モノミアルの和
 monom        = [formula *] nfpow [* ...]
     モノミアル
 nfpow        = nf | nf^(nf)
     冪乗部分の標準形
 formula      = Risa object

Expr を fnode標準形に変換する. Modeにより標準形への展開アルゴリズムを指定できる.
展開は再帰的である.
入力が fnode に変換された初期状態では + や * は子供が2人の binary operator (b_op) であるが, qt_normalize を作用させることにより, + や * は任意人数の子供を持てる n-ary operator に変換される.
n-ary operator を基礎とした fnode標準形を用いることにより, パターンマッチ用のパターンの数を減らせることが経験的にわかっている.
Mode=0. 展開しない. これが既定の動作.
Mode=1. 展開する. ただし x*x 等を x^2 等に変換
Mode=2. 展開する. ただし x*x 等を x^2 等に変換しない.

Mode の違いについては以下の例も参考に.

ctrl("print_quote",2);
A=quote((x-y)*(x+y));
   出力:  ((x)-(y))*((x)+(y))
B=qt_normalize(A,0);
   出力: ((x)+((-1)*(y)))*((x)+(y))  Mode=0. 展開はされない. +, * は n_op (nary-op) へ.
quotetolist(B);
   出力: [n_op,*,[n_op,+,[internal,x],[n_op,*,[internal,-1],[internal,y]]],[n_op,+,[internal,x],[internal,y]]]

B=qt_normalize(A,1);
   出力: ((x)^(2))+((x)*(y))+((-1)*((y)^(2)))+((-1)*(y)*(x))
           Mode=1. 展開する. +, * は n_op (nary-op) へ. 巾をまとめる.
quotetolist(B);
   出力: [n_op,+,[b_op,^,[internal,x],[internal,2]],[n_op,*,[internal,x],[internal,y]],[n_op,*,[internal,-1],[b_op,^,[internal,y],[internal,2]]],[n_op,*,[internal,-1],[internal,y],[internal,x]]]

qt_normalize(A,2);
   出力: ((x)*(x))+((x)*(y))+((-1)*(y)*(x))+((-1)*(y)*(y))
           Mode=2. 展開する. +, * は n_op (nary-op) へ. 巾は使わない.
quotetolist(B);
   出力: [n_op,+,[b_op,^,[internal,x],[internal,2]],[n_op,*,[internal,x],[internal,y]],[n_op,*,[internal,-1],[b_op,^,[internal,y],[internal,2]]],[n_op,*,[internal,-1],[internal,y],[internal,x]]]

qt_normalize(`x^2,2);
   出力: (x)*(x)
       Mode=2. 巾は使わない. n-ary の * へ.

参照: nqt_match, nqt_match_rewrite, @ref{quotetolist}, @ref{quote_to_funargs}

ChangeLog

—–まだ書いてない.

2.1.9 `qt_set_coef`

qt_set_coef(ParamList): :: 以下 ParamList に現れる多項式変数を変数とする有理関数体を係数とする非可換多項式を扱う.

return: リスト
ParamList: リスト

以下 ParamList に現れる多項式変数を変数とする有理関数体を係数とする非可換多項式を扱う.
この宣言をしないと係数体を数とする非可換多項式として計算する.
qt_normalize およびその機能を用いる関数がこの機能の影響を受ける.
qt_comp 関数がこの機能の影響を受ける.

ctrl("print_quote",2);
qt_set_coef([a]);
B=qt_normalize(quote((a*x+a)^2),2);
     出力: ((a^2)*(x)*(x))+((2*a^2)*(x))+(a^2)
qt_normalize(B+B,2);
     出力: ((2*a^2)*(x)*(x))+((4*a^2)*(x))+(2*a^2)

参照: qt_normalize

ChangeLog

—–まだ書いてない.

2.1.10 `qt_set_ord`

qt_set_ord(VarList): :: VarList を変数順序とする.

return: リスト
VarList: リスト

VarList を辞書式に用いた変数順序を以下使用する.
この宣言をしないとある不定元についての既定の辞書式順序—–まだ書いてない—を用いて項を比較する. VarList に現れない変数についてはこの順序が適用される.
qt_normalize およびその機能を用いる関数がこの機能の影響を受ける.
qt_comp 関数がこの機能の影響を受ける.

ctrl("print_quote",2);
qt_normalize(quote(x+y),2);
     出力: (x)+(y)
qt_set_ord([y,x]);
     出力: [y,x,z,u,v,w,p,q,r,s,t,a,b,c,d,e,f,g, 以下省略 ]
qt_normalize(quote(x+y),2);
     出力: (y)+(x)

参照: qt_normalize, nqt_comp

ChangeLog

—–まだ書いてない.

2.1.11 `qt_set_weight`

qt_set_weight(WeightVector): :: 変数について weight ベクトルを設定する.

return: リスト
WeightVector: リスト

fnode f の weight w(f) は次の式で計算する.

 f が葉の場合は原則 0. qt_weight_vector で weight が与えられている不定元に
 ついてはその値.

 f がnodeの場合は次の規則で再帰的にきめる.
   w(f+g) = max(w(f),w(g))
   w(f g) = w(f) + w(g)
   w(f^n) = n w(f)
   関数については? -----まだ書いてない.

WeightVector でまず順序の比較をして, それから qt_set_order による順序, 最後に既定の順序で比較する. WeightVector に現れない変数についての weight は 0 となる.
qt_normalize およびその機能を用いる関数がこの機能の影響を受ける. qt_normalize での展開では, この順序を用いて項がソートされる.
qt_comp およびその機能を用いる関数がこの機能の影響を受ける.
weight ベクトルによる順序比較についてはグレブナ基底の節dp_gr_mainも参照.

ctrl("print_quote",2);
qt_set_weight([[x,-1],[y,-1]]);
     結果: [[x,-1],[y,-1]]
qt_normalize(quote( 1+(x+y)+(x+y)^2),1);
     結果: (1)+(y)+(x)+((y)^(2))+((y)*(x))+((x)^(2))+((x)*(y))

参照: qt_normalize, qt_set_ord, qt_set_weight, dp_gr_main

ChangeLog

—–まだ書いてない.

2.1.12 `nqt_comp`

nqt_cmp(Expr1,Exprt2): :: Expr1 と Expr2 の順序を比較する.

return: 整数
Expr1, Expr2: quote型

Expr1 と Expr2 の順序を比較する.
Expr1 > Exprt2 なら 1.
Expr1 < Exprt2 なら -1.
Expr1 = Exprt2 (おなじ順序) なら 0.

ctrl("print_quote",2);
qt_set_ord([y,x]); qt_set_weight([[x,-1],[y,-1]]);
[nqt_comp(`x,`y), nqt_comp(`y,`x), nqt_comp(`x,`x)];
     出力: [-1,1,0]

参照: qt_normalize, qt_set_ord, qt_set_weight

ChangeLog

まだ書いてない.

2.1.13 `qt_is_var`, `qt_is_coef`

qt_is_var(Expr): :: Expr が不定元に対応する quote なら 1 を戻す.
qt_is_coef(Expr): :: Expr が係数の有理関数体に属するとき 1 を戻す.

return: 整数
Expr: quote型

Expr が不定元に対応する quote なら 1 を戻す. そうでないとき 0 を戻す.

[qt_is_var(quote(x)), qt_is_var(quote(3/2))];
     出力: [1,0]

参照: qt_rewrite, nqt_match_rewrite

ChangeLog

—–まだ書いてない.

2.1.14 `qt_rewrite`

qt_rewrite(Expr,Rules,Mode): :: Expr を規則集合 Rules を用いて書き換える.

return: quote型
Expr: quote型
Rules: リスト
Mode: 整数

ユーザ言語を用いて定義された関数. import("noro_rewrite.rr") しておくこと. (noro_rewrite.rr が OpenXM/lib/asir-contrib に存在しない場合ソースの OpenXM/src/asir-contrib/testing/noro/new_rewrite.rr をコピー)
Expr を規則集合 Rules を用いて書き換える.
規則の適用は fnode木に対して再帰的である. 一方 nqt_match_rewrite ではトップレベルのみに規則が適用される.
規則集合 Rules の各要素の書き方は nqt_match() の Pattern と同じ書き方. つまり [パターン, 書き換え結果] または [パターン, 条件, 書き換え結果].
Mode の意味は qt_normalize の Mode と同様. パターンマッチ, 書き換えは Mode で qt_normalize() されてから遂行される.

注意: 数学的には X*Y=Y*X が可換性を与える規則だが, これをそのまま規則として与えると書き換えが停止しない. 次の例では, 上の例のように順序比較し, たとえば, 順序が大きくなる場合のみに書き換えるべきである.

import("noro_rewrite.rr");
R=[[`X*Y,`nqt_comp(Y*X,X*Y)>0, `Y*X]];
qt_rewrite(`(x-y)^2,R,2);
     出力: quote(x*x+-2*x*y+y*y)

外積代数の計算 (asir-contrib をロードした状態).

import("noro_rewrite.rr");
Rext0=[quote(X*Y),quote(qt_is_var(X) && qt_is_var(Y) && nqt_comp(Y,X)>0),
                  quote(-Y*X)];
Rext1=[quote(X^N),quote(eval_quote(N)>=2),quote(0)];
Rext2=[quote(X*X),quote(0)];
Rext=[Rext0,Rext1,Rext2];
qt_rewrite(quote( (x+2*y)*(x+4*y) ), Rext,1);
     出力: 2*x*y

qt_set_coef([a,b,c,d]);
qt_rewrite(quote((a*x+b*y)*(c*x+d*y)), Rext,1);
     出力: (d*a-c*b)*x*y

微分の計算 (asir-contrib をロードした状態).

import("noro_rewrite.rr");
qt_set_coef([a,b]);
Rd1=[`d(X+Y), `d(X)+d(Y)];
Rd2=[`d(X*Y),`d(X)*Y+X*d(Y)];
Rd3=[`d(N), `qt_is_coef(N), `0];
Rd4=[`d(x),`1];
Rd=[Rd1,Rd2,Rd3,Rd4];
B=qt_rewrite( `d( (a*x+b)^3),Rd,2);
     出力: quote(3*a^3*x*x+6*b*a^2*x+3*b^2*a)
fctr(eval_quote(B));
     出力: [[3,1],[a,1],[a*x+b,2]]

参照: nqt_match, nqt_match_rewrite, qt_normalize

ChangeLog

qt 系の関数の原型は OpenXM/src/asir-contrib/testing/tr.rr である. このユーザ言語による開発が 2005年の春まで行われ, そのあと組み込み関数主体の qt 系の関数が開発された.
qt 系の関数についてのその他の参考文献: OpenXM/doc/Papers/2005-rims-noro.tex および OpenXM/doc/Papers/2005-rims-noro.tm (TeXmacsの記事).
Todo: qt 系の関数を用いたおもしろい計算を Risa/Asir ジャーナルの記事として書く.

この文書は3月 16, 2025にtexi2html 5.0を用いて生成されました。

2.1 クオート

2.1.1 quotetotex, quotetotex_env

2.1.2 objtoquote

2.1.3 flatten_quote

2.1.4 quote_to_funargs, funargs_to_quote, remove_paren, get_function_name

2.1.5 eval_quote

2.1.6 nqt_match

2.1.7 nqt_match_rewrite

2.1.8 qt_normalize

2.1.9 qt_set_coef

2.1.10 qt_set_ord

2.1.11 qt_set_weight

2.1.12 nqt_comp

2.1.13 qt_is_var, qt_is_coef

2.1.14 qt_rewrite

2.1.1 `quotetotex`, `quotetotex_env`

2.1.2 `objtoquote`

2.1.3 `flatten_quote`

2.1.4 `quote_to_funargs`, `funargs_to_quote`, `remove_paren`, `get_function_name`

2.1.5 `eval_quote`

2.1.6 `nqt_match`

2.1.7 `nqt_match_rewrite`

2.1.8 `qt_normalize`

2.1.9 `qt_set_coef`

2.1.10 `qt_set_ord`

2.1.11 `qt_set_weight`

2.1.12 `nqt_comp`

2.1.13 `qt_is_var`, `qt_is_coef`

2.1.14 `qt_rewrite`