next | previous | forward | backward | up | top | index | toc | home

allGenerators -- list of all generators

Synopsis

Usage:
allGenerators R
Inputs:
- R, a ring
Outputs:
- a list, of every generator of R over the prime field or the integers

Description

Returns the list of all of the generators, as elements of R.

i1 : A = GF(9,Variable=>a)

o1 = A

o1 : GaloisField

i2 : B = A[r,s,t]

o2 = B

o2 : PolynomialRing

i3 : generators B

o3 = {r, s, t}

o3 : List

i4 : allGenerators B

o4 = {r, s, t, a}

o4 : List

i5 : C = B[x,y,z]/(x^2-a*x-r)

o5 = C

o5 : QuotientRing

i6 : generators C

o6 = {x, y, z}

o6 : List

i7 : allGenerators C

o7 = {x, y, z, r, s, t, a}

o7 : List

This same order is used when creating ring maps from this ring. The following ring map from C --> A[u,v] sends x|-->0, y|-->u, z|-->v, r|-->0, s-->av+1, t|-->1.

i8 : D = A[u,v];

i9 : F = map(D, C, {0, u, v,  0, a*v+1, 1})

o9 = map(D,C,{0, u, v})

o9 : RingMap D <--- C

i10 : F (x+s*y)

o10 = a*u*v + u

o10 : D

See also

generators -- provide matrix or list of generators
vars -- variables
substitution and maps between rings

Ways to use `allGenerators` :

allGenerators(Ring)