symmetric algebras

Polynomial rings are symmetric algebras with explicit generators, and we have already seen how to construct them. But if you have a module, then its symmetric algebra can be constructed with symmetricAlgebra.

i1 : R = QQ[a..d];

i2 : S = symmetricAlgebra R^3

o2 = S

o2 : PolynomialRing

i3 : describe S

o3 = QQ [x , x , x , a, b, c, d, Degrees => {{1, 0}, {1, 0}, {1, 0}, {0, 1},
          0   1   2
     ------------------------------------------------------------------------
     {0, 1}, {0, 1}, {0, 1}}]

i4 : S_0+S_4

o4 = x  + b
      0

o4 : S

i5 : S_"x_0"

o5 = x
      0

o5 : S

To specify the names of the variables when creating the ring, use the Variables option.

i6 : S = symmetricAlgebra(R^3, Variables => {t,u,v})

o6 = S

o6 : PolynomialRing

We can construct the symmetric algebra of a module that isn't necessarily free.

i7 : symmetricAlgebra(R^1/(R_0,R_1^3), Variables => {t})

     QQ [t, a, b, c, d, Degrees => {{1, 0}, {0, 1}, {0, 1}, {0, 1}, {0, 1}}]
o7 = -----------------------------------------------------------------------
                                            3
                                   (t*a, t*b )

o7 : QuotientRing