map(Ring,Ring,List) -- make a ring map

Synopsis

Usage:
map(R,S,m)
Function: map
Inputs:
- R, a ring, the target ring
- S, a ring, the source ring
- m, a list, of n elements of R, where n is the number of variables in the polynomial ring S, or a list of pairs x => r, where x is a generator of S and r is an element of R, specifying that x is to be sent to r.
Outputs:
- a ring map, the ring homomorphism from S to R which sends the i-th variable of S to the i-th entry in m, or in the second case, performs the indicated substitutions.
Optional inputs:
- Degree => ..., -- set the degree of a map
- DegreeMap => ...,

i1 : R = ZZ[x,y];

i2 : S = ZZ[a,b,c];

i3 : f = map(R,S,{x^2,x*y,y^2})

               2        2
o3 = map(R,S,{x , x*y, y })

o3 : RingMap R <--- S

i4 : f(a+b+c^2)

      4    2
o4 = y  + x  + x*y

o4 : R

i5 : g = map(R,S,{a=>x^2,b=>x*y,c=>y^2})

               2        2
o5 = map(R,S,{x , x*y, y })

o5 : RingMap R <--- S

i6 : g(a+b+c^2)

      4    2
o6 = y  + x  + x*y

o6 : R