monoid -- make or retrieve a monoid

Synopsis

• Usage:

  monoid [a,b,c,...]

• Inputs:

  • a,b,c,..., a list of variables, as well as optional arguments
• Outputs:

  • a general ordered monoid, a new monoid
• Optional inputs:

  • DegreeRank => an integer, default value null, the length of each multidegree
  • Degrees => a list, default value null, a list of degrees or multidegrees of the variables. Each degree is an integers, and each multidegree is a list of integers. Degrees will be converted into multidegrees of length 1.
  • Inverses => a Boolean value, default value false, whether negative exponents will be allowed, making the monoid into a group
  • Global => a Boolean value, default value true, whether this ring is to be a global ring. If it is a global ring, and the Inverses=>true is not specified, then an error is signalled if any of the variables are not greater than 1 in the monomial ordering, as required by the standard theory of Groebner bases.
  • MonomialOrder => a list, default value {GRevLex, Position => Up}, an option for specifying the monomial ordering, see MonomialOrder
  • MonomialSize => an integer, default value 32, the minimum number of bits to be used for storing each exponent in a monomial. The exponents are stored as signed binary numbers, so n bits allows an exponent as large as 2^n-1-1. Useful values are 8, 16, and 32.
  • SkewCommutative => default value {}, specifies whether some of the variables skew-commute with each other. The value true indicates that all of the variables skew-commute. Otherwise, the value of the option should be a list of variables, variables names, or integers that will be interpreted as indices of the variables.
  • Variables => default value null, a list of variables names, or the number of variables to be made. This option is useful for those situations when one doesn't care about the names of the variables in a ring or monoid, or when one is creating a tensor product ring, symmetric algebra, or other ring, and one wants control over the names of the ring variables.
  • VariableBaseName => a symbol, default value null, a symbol x to be used as the base for constructing a list of subscripted variable names of class IndexedVariable, of the form x_0, ..., x_(n-1).
  • Weights => a list, default value {}, a list of integers, or a list of lists of integers, that specify weights for the variables. The orderings by these weight vectors is prepended to the list of orderings provided by the MonomialOrder option.
  • WeylAlgebra => a list, default value {}, a list of options of the form x=>dx, which specifies that dx plays the role of the derivative with respect to x in the resulting Weyl algebra when this monoid is made into a polynomial ring.
  • Heft => a list, default value null, a list of integers: its dot product (presumably positive) with the multidegrees of the variables will be prefixed to the multidegrees of the variables, as an internal adjustment
  • Adjust => a function, default value identity, a linear function for transforming the externally visible multidegrees of the variables into multidegrees whose first component is positive
  • Repair => a function, default value identity, a linear function for transforming internally used multidegrees (whose first component is positive) of variables into the externally visible multidegrees. This function must be the inverse of the Adjust function.

Description

i1 : M = monoid [a,b,c,Degrees=>{2,3,4}]

o1 = M

o1 : GeneralOrderedMonoid

i2 : degrees M

o2 = {{2}, {3}, {4}}

o2 : List

i3 : M_0 * M_1^6

        6
o3 = a*b

o3 : M

i4 : a

o4 = a

o4 : M

i5 : use M

o5 = M

o5 : GeneralOrderedMonoid

i6 : a * b^6

        6
o6 = a*b

o6 : M

i7 : options M

o7 = OptionTable{Adjust => identity                                     }
                 DegreeRank => 1
                 Degrees => {{2}, {3}, {4}}
                 Global => true
                 Heft => 
                 Inverses => false
                 MonomialOrder => {GRevLex => {2, 3, 4}, Position => Up}
                 MonomialSize => 32
                 Repair => identity
                 SkewCommutative => {}
                 VariableBaseName => 
                 Variables => {a, b, c}
                 Weights => {}
                 WeylAlgebra => {}

o7 : OptionTable

i8 : R = ZZ[x,y, Degrees => {-1,-2}, Repair => d -> -d, Adjust => d -> -d]

o8 = R

o8 : PolynomialRing

i9 : degree \ gens R

o9 = {{-1}, {-2}}

o9 : List

i10 : transpose vars R

o10 = {1} | x |
      {2} | y |

              2       1
o10 : Matrix R  <--- R

i11 : R = ZZ/101[x,dx,y,dy,WeylAlgebra => {x=>dx, y=>dy}]

o11 = R

o11 : PolynomialRing

i12 : dx*x

o12 = x*dx + 1

o12 : R

i13 : dx*x^10

       10        9
o13 = x  dx + 10x

o13 : R

i14 : dx*y^10

          10
o14 = dx*y

o14 : R

i15 : R = ZZ[x,y,z,SkewCommutative=>{x,y}]

o15 = R

o15 : PolynomialRing

i16 : x*y

o16 = x*y

o16 : R

i17 : y*x

o17 = -x*y

o17 : R

i18 : x*z-z*x

o18 = 0

o18 : R

i19 : R = QQ[a..d, Weights=>{1,2,3,4}]

o19 = R

o19 : PolynomialRing

i20 : monoid R

o20 = [a, b, c, d]

o20 : GeneralOrderedMonoid